excel里用哪些函数可以查找数据？

一、HYPERLINK函数（=HYPERLINK('#C2','跳转到C2')）

这个函数则是用于跳转使用，有时候需要点击某一个单元格，然后跳转到其他的单元格，

那么这个时候就可以使用HYPERLINK函数，自动就可以快速进行跳转了。

二、INDEX函数（=INDEX(A2:C5,1,2)）

INDEX函数则可以帮助从指定的单元格选择值，这个则主要可以帮查找相应的单元格里面相关的数值单位。

三、INDIRECT函数

对于文本值里面指定的引用，也可以有相对应的方法进行解决，只要使用INDIRECT 数，之后输入=INDIRECT（”A1”）对于A1单元格的文本进行引用，然后使A1的值为B2，最终就可以返回1了。

四、LOOKUP函数（=LOOKUP(1,0/(A3:A15='张三')，B3:B15)）

在向量或者数组里面，我们也可以对对应的值进行相关的查重，虽然方法很多，=LOOKUP(1，0/(条件区域=条件)，查询区域)这个方法，可以用它找到固定人名或其他关键组的数值。

五、MATCH函数（=MATCH(C1,A1:E1,1)）

同样的，MATCH函数也是用于引用或数组中的值的查找，可以帮助快速地找到这些数据内容。

参考资料来源：百度百科-excel函数

在excel函数公式中满足2个条件，查找对应数据，有很多种方法，不过通过你的图片说明，完全可以用VLOOKUP函数来做，简单方便。

公式如下:

=VLOOKUP($B15,$B$1:$D$7,C$14+1,)

VLOOKUP函数一共四个参数:

1、查找的值，姓名:

2、被查找的数据区域，也就是需要找出数据对应的那些区域(注意:首列必须包含参数1的值)

3、返回参数2区域的第N列，由C14＋1

4、查找模式为精确查找。

可以利用像SUM函数、lookup函数、VLOOKUP+CHOOSE函数、OFFSET+MATCH函数、INDIRECT+MATCH函数的组合等方式来对EXCEL里的内容进行精确查找。

如下图所示，根据第9行的产品和型号，从上面表中查找“销售数量”，结果如C10所示：

SUM函数：

公式{=SUM((A2:A6=A9)*(B2:B6=B9)*C2:C6)}

公式简介：使用(条件)*（条件)因为每行符合条件的为0，不符合的为1，所以只有条件都符合的为非零数字。所以SUM求和后就是多条件查找的结果

SUMPRODUCT函数：

公式：=SUMPRODUCT((A2:A6=A9)*(B2:B6=B9)*C2:C6)

公式简介：和SUM函数用法差不多，只是SUMPRODUCT函数不需要数组运算

MAX函数：

{=MAX((A2:A6=A9)*(B2:B6=B9)*C2:C6)}

SUM是通过求和把符合条件的提出来，这里是使用MAX提取出最大值来完成符合条件的值提取。

lookup函数：

公式1=LOOKUP(A9&B9,A2:A6&B2:B6,C2:C6)

公式简介：LOOKUP函数可以直接进行数组运算。查找的连接起来，被查找区域也连接起来。

公式2：=LOOKUP(1,0/((A2:A6=A9)*(B2:B6=B9)),C2:C6)

公式3=LOOKUP(1,0/((A2:A6&B2:B6)=(A9&B9)),C2:C6)

公式4=LOOKUP(1,1/(((A2:A6=A9)+(B2:B6=B9))=2),C2:C6)

MIN+IF函数：

公式=MIN(IF((A2:A6=A9)*(B2:B6=B9),C2:C6))

SUM+IF函数：

公式=SUM(IF(A2:A6=A9,IF(B2:B6=B9,C2:C6,0),0))

INDEX+MATCH函数组合：

公式1：{=INDEX(C2:C6,MATCH(A9&B9,A2:A6&B2:B6,0))}

公式2：{=INDEX(C2:C6,MATCH(1,(A9=A2:A6)*(B9=B2:B6),0))}

OFFSET+MATCH函数：

公式=OFFSET(C1,MATCH(A9&B9,A2:A6&B2:B6,0),)

INDIRECT+MATCH函数：

公式 =INDIRECT("C"&MATCH(A9&B9,A1:A6&B1:B6,0))

VLOOKUP+CHOOSE函数：

公式 ：=VLOOKUP(A9&B9,CHOOSE({1,2},A2:A6&B2:B6,B2:C6),2,0)

HLOOKUP+TRANSPOSE+CHOOSE函数：

公式=HLOOKUP(A9&B9,TRANSPOSE(CHOOSE({1,2},A2:A6&B2:B6,B2:C6)),2,0)

VLOOKUP+IF函数：

公式1 =VLOOKUP(A9&B9,IF({1,0},A2:A6&B2:B6,B2:C6),2,0)

公式2=VLOOKUP(A9&"|"&B9,A31:D35,4,0)‘添加辅助列

SUMIFS函数：

excel2007中开始提供的函数SUMIFS

=SUMIFS(C1:C6,A1:A6,A9,B1:B6,B9)

数据库函数：

=DSUM(A1:C6,3,A8:B9)

=DGET(A1:C6,3,A8:B9)

=DAVERAGE(A1:C6,3,A8:B9)

=DMAX(A1:C6,3,A8:B9)

=DMIN(A1:C6,3,A8:B9)

=DPRODUCT(A1:C6,3,A8:B9)

---